PDA

Vollständige Version anzeigen : Tabelleb vergleichen und fehlende Werte ergänzen


thecrazykaktus
22.09.2016, 21:57
Hallo,

ich ich würde gerne mithilfe von VBA ein Problem Lösen.
Ich habe 2 Tabellen. Tabelle 1: SAA_List, Tabelle 2: Source List

In beiden Tabellen stehen in Spalte A "IDs". In der Source Tabelle stehen die Ausgangswerte.

Nun möchte ich gerne mithilfe von VBA prüfen, welche "IDs" in der "SAA_List" fehlen und diese automatisch ergänzen lassen.
Schön wäre es noch wenn die ergänzten Werte farblich hervorgehoben werden.

Kann mir hier jemand helfen?

rastrans
22.09.2016, 22:54
Sub IdVergleich()
Dim wsSource As Worksheet
Dim wsSAA As Worksheet
Dim rng As Range
Dim lngZeileSource As Long
Dim lngZeileSAA As Long

Set wsSource = Worksheets("Source List")
Set wsSAA = Worksheets("SAA_List")

lngZeileSAA = wsSAA.Cells(Rows.Count, 1).End(xlUp).Row
lngZeileSource = 2
Do Until IsEmpty(wsSource.Cells(lngZeileSource, 1))
Set rng = wsSAA.Columns(1).Find(What:=wsSource.Cells(lngZeileSource, 1).Value, LookAt:=xlWhole)
If rng Is Nothing Then
lngZeileSAA = lngZeileSAA + 1
With wsSAA.Cells(lngZeileSAA, 1)
.Value = wsSource.Cells(lngZeileSource, 1).Value
.Interior.Color = 255
End With
End If
lngZeileSource = lngZeileSource + 1
Loop
End Sub

steve1da
22.09.2016, 23:39
Hola,

zur Info...

http://www.clever-excel-forum.de/thread-6601.html

Gruß,
steve1da