PDA

Vollständige Version anzeigen : Spez. Suchfunktion mit Ausgabe


4iLi
17.07.2014, 11:49
Hallo Zusammen,

leider als kein Profi ist es für mich ein mega Aufwand für diese eine Funktion ein VBA Makros zu schreiben. Nutze Excel 2010 und das Problem ist, ich habe 52 Reiter, diese sind so benannt: KW01 bis KW52. In diesen Reitern sind Nummern die mich interessieren, die Nummern sehen so aus 21P5289, 22P5789, 23P8852. Ich möchte das Excel mir alle Nummern aus einer bestimmten vorher festgelegten KW, Beispiel KW25 die Nummern herausholt die mit 22P, 21P, 23P usw. herausholt und in einer spalte positioniert im neuen Reiter.

Jetzt meine Frage, ist das möglich? Weil ich werde hier langsam wahnsinnig, bitte um HILFE…

Mc Santa
17.07.2014, 12:06
Hallo,

lade bitte eine Beispieltabelle für die Kalenderwochen 1-3 hoch und dazu eine Beispielhafte Ausgabe (von Hand) für eines dieser Tabellenblätter.

Das Makro dazu lässt sich dann bestimmt finden :)

VG

4iLi
17.07.2014, 12:27
Hier ein Beispiel

4iLi
17.07.2014, 12:41
Ich brauche hier Übels Zeit bis ich da die Nummern herauskopiert habe. Das wäre genial von euch da irgendwie eine simple Liste herauszugeben in einem extra Reiter die wirklich nach meiner Vorgabe nach Nummern mit dem Anfang „21P“ „22P“ „23P“ sucht.

Das wäre genial!

Mc Santa
17.07.2014, 13:15
Hallo,

ich habe dir mal ein Beispiel erstellt.
Freúe mich über Feedback :)

VG

4iLi
17.07.2014, 13:50
omg, das ist genial, und kann man zu diesen Spalten den Wochen Tag von oben mitgeben in die Zweite Spalte ich hab das vor Aufregung total verpeilt... Oben sind ja die Wochentage auch da wenn die dann gegenüber 2 Spalte auftauchen ist das perfekt!

Und ich möchte dir auch vom ganzen Herzen danken, du hast wirklich was geschaffen, was meine Nerven schont.

Mc Santa
17.07.2014, 14:00
Steht denn der Wochentag immer in Zeile 4 oder Zeile 5? Das ist in der Datei nicht konstant.

VG

4iLi
17.07.2014, 14:08
Zeile 5 Wochentag
Zeile 3 Tag + Monat

Mc Santa
17.07.2014, 14:16
Hallo,

hier noch einmal leicht modifiziert die neue Datei:
Für alle, die keine Downloads haben, hier auch der Code aus der Datei
Option Explicit

Sub nummernFinden()
Dim strIn As String
strIn = InputBox("Welche KW? (01-52)", "Bitte KW eingeben", "01")

Dim fRng As Range
Dim firstAddress As String

If wsExists("KW" & strIn) Then
With Worksheets("KW" & strIn)

Set fRng = .Cells.Find(What:="??P", After:=.Cells(1, 1), LookIn:=xlValues, LookAt:= _
xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False _
, SearchFormat:=False)

If Not fRng Is Nothing Then
Worksheets("Ausgabe").Cells(1, 1).EntireColumn.Clear
Worksheets("Ausgabe").Cells(1, 2).EntireColumn.Clear
firstAddress = fRng.Address
Do
Worksheets("Ausgabe").Cells(Rows.Count, 1).End(xlUp).Offset(1) = fRng.Value
Worksheets("Ausgabe").Cells(Rows.Count, 1).End(xlUp).Offset(, 1) = .Cells(5, fRng.Column).Value
Set fRng = .Cells.FindNext(fRng)
Loop Until fRng.Address = firstAddress
Else
MsgBox "Keine Nummern gefunden"
End If
End With
Else
MsgBox "Blatt nicht gefunden!"
End If
End Sub

Function wsExists(wsName As String) As Boolean
On Error Resume Next
wsExists = Worksheets(wsName).Index > 0
End Function

VG