MS-Office-Forum

Zurück   MS-Office-Forum > Microsoft Office > Microsoft Excel
Registrieren Forum Hilfe Alle Foren als gelesen markieren

Banner und Co.

Antworten
Ads
Themen-Optionen Ansicht
Alt 25.03.2010, 13:07   #1
chris-kaiser
MOF Guru
MOF Guru
Strahlen Hinweis - Makrorekorder - Code anpassen für Einsteiger

oder auch "Makrorekorder was machst du da bloß"

Hallo allerseits

Dieser Artikel richtet sich an alle, die Makros aufzeichnen und auch ein wenig bearbeiten wollen.

Notwendige Vorkenntnisse:
Wie man Makros aufzeichnet, die Entwicklungsumgebung öffnet
Artikelinhalt:
Weg mit den Select, Erklärung des Objektmodells, Grundlegende VBABegriffe

Wenn Sie die Beispiele testen wollen, öffnen Sie eine neue leere Mappe

Starten Sie eine Aufzeichnung:
  • Geben sie dem Makro den Namen Aufzeichnung
  • Markieren Sie Zelle C4
  • schreiben Sie in diese Zelle MOF
  • drücken Sie die Taste Enter (Return)
  • schreiben sie in die Zelle Übung
  • drücken Sie die Taste Enter (Return)
  • schreiben sie in die Zelle =Anzahl2(C4:C5)
  • drücken Sie die Taste Enter (Return)
Wenn sie sich nun das Makro anschauen, müßte folgendes in einem allgemeinen Modul der Mappe abgelegt sein:

Code:

Sub Aufzeichnung()
'
' Aufzeichnung Makro
'
    Range("C4").Select
    ActiveCell.FormulaR1C1 = "MOF"
    Range("C5").Select
    ActiveCell.FormulaR1C1 = "Übung"
    Range("C6").Select
    ActiveCell.FormulaR1C1 = "=COUNTA(R[-2]C:R[-1]C)"
    Range("C7").Select
End Sub
tja, funktioniert aber der VBACode ist irgendwie verwirrend.
Schauen wir uns das mal genauer an.

Code:

Sub Aufzeichnung()
    'markiere den BEREICH C4
    Range("C4").Select
    'in der aktiven Zelle füge über die FormelZeileSpalte den Text MOF ein
    ActiveCell.FormulaR1C1 = "MOF"
    'markiere den BEREICH C5
    Range("C5").Select
    'in der aktiven Zelle füge über die FormelZeileSpalte den Text Übung ein
    ActiveCell.FormulaR1C1 = "Übung"
    'markiere den BEREICH C6
    Range("C6").Select
    'in der aktiven Zelle füge über die FormelZeileSpalte die Formel =ANZAHL2(C4:C5) ein
    'wobei jetzt das "=COUNTA(R[-2]C:R[-1]C)" irgenwie verwirrend sein kann ^^
    ActiveCell.FormulaR1C1 = "=COUNTA(R[-2]C:R[-1]C)"
    'markiere den BEREICH C7
    Range("C7").Select
End Sub
Im Code habe ich jetzt die einzelnen Zeilen dokumentiert, Sie können selbiges auch machen, indem sie ein Hochkomma an erster Stelle einfügen.
Der Rekorder gaukelt jetzt einem vor, das der Cursor bewegt werden muß, nur diese SELECT Anweisungen sind vollkommen überflüssig!
Ebenso diese Standardeigenschaft bei Eingaben (.FormulaR1C1), das normale Eingaben zuläßt, sowie auch Formeln. Da der Rekorder eben nicht weiß, ob ich eine Formel oder ein „normaler“ Eintrag erzeugt wird, wird eben diese Eigenschaft bei einer Aufzeichnung genutzt.
Für Zelleingaben sollte die Eigenschaft .value gewählt werden. (diese könnte in VBA sogar weggelassen werden, da dies die Default Eigenschaft ist.)

Code:

Range("C4").Select
ActiveCell.FormulaR1C1 = "MOF"
 
 
markiere Bereich C4 -> damit diese zur aktiven Zelle wird und dort was reingeschrieben werden kann?
Warum nicht gleich in Zelle C4 was eingeben
Code:

Range("C4").Value = "MOF"
 
 
Bereich C4 soll den Eintrag MOF erhalten.
Vielleicht ist Ihnen aufgefallen, dass ich für die Zelle C4 die Bezeichnung Bereich verwende.
dazu eine kleine Exkursion des Objektmodells in Excel
  1. Application-Objekt (kann bei einfachen Makros, die durch Aufzeichnung entstanden sind wegfallen)
  2. Workbook-Objekt (in welcher Arbeitsmappe)
  3. Worksheet-Objekt (in welcher Tabelle)
  4. Range-Objekt (in welchem BEREICH)
Beispiel:
Code:

Excel.Application.Workbooks("Name_der_Mappe.xls").Worksheets("Name_der_Tabelle").Range("C1").Value = "Eintrag"
 
 
das Excel.Application kann bei VBA Codes wegfallen!

das würde den Text „Eintrag“ in der Mappe „Name_der_Mappe“ im Tabellenblatt „Name_der_Tabelle“ in die Zelle C1 vornehmen, sofern diese Mappe auch geöffnet ist.

betrachten wir mal das Range-Objekt
Range ist der Standard bei Aufzeichnungen, kann aber wenn auch durch Cells ersetzt werden.

statt
Range("C1")
kann auch
cells(1,3)
verwendet werden.

cells(Zeile,Spalte) Zeile 1 und Spalte 3 sind C1
um einen Code besser lesen zu können, kann auch cells(1,"C") verwendet werden.

Es gibt auch eine gültige Kurzform

[c1].value="Test"
würde auch funktionieren.

Soll ein Zellbereich bearbeitet werden.
Code:

Range("A1:D3").value=1
das würde im Bereich von A1 bis D3 eine Eins eintragen.
Range kann aber auch noch anders wiedergegeben werden
Code:

Sub Range_Varianten()
'es wird hier immer der Bereich von A1:D3 mit einer Eins ausgefüllt
'alle diese Zeilen führen das gleiche aus
Range("A1", Cells(3, 4)).Value = 1
Range(Cells(1, 1), Cells(3, 4)).Value = 1
Range(Cells(1, "A"), Cells(3, "D")).Value = 1
Range(Cells(1, 1), "D3").Value = 1
Range("A1", "D3").Value = 1
Range("A1:D3").Value = 1
End Sub
Unser aufgezeichnetes Makro können wir mal so ändern.
Code:

Sub Aufzeichnung()
    Range("C4").Value = "MOF"
    Range("C5").Value = "Übung"
    Range("C6").FormulaR1C1 = "=COUNTA(R[-2]C:R[-1]C)"
End Sub
Die Formel =ANZAHL2(C4:C5) ist aber nicht gerade gut leserlich.

statt dem .FormulaR1C1 kann auch

.Formula
.FormulaLocal


verwendet werden
Code:

    '.FormulaLocal hängt mit der Ländereinstellung zusammen
    'dies kann zu Fehlern führen wenn die Mappe, mal über Landesgrenzen verschickt werden sollte ^^
    Range("C6").FormulaLocal = "=ANZAHL2(C4:C5)"
    '.Formula internationale Bezeichnung funktioniert immer
    'durch die Aufzeichnung ist der engl.Formelbegriff ja schon vorhanden
    'diese Variante würde ich persönlich empfehlen
    Range("C6").Formula = "=COUNTA(C4:C5)"
Unser erster aufgezeichneter Code könnte überarbeitet nun so aussehen.
Code:

Sub Aufzeichnung()
    Range("C4").Value = "MOF"
    Range("C5").Value = "Übung"
    Range("C6").Formula = "=COUNTA(C4:C5)"
End Sub
Nun noch ein Beispiel mit einer aufgezeichneten Formel.
  • Starten Sie die Aufzeichnung
  • vergeben Sie für das Makro den Namen Formel
  • klicken Sie auf die Zelle H1
  • geben sie folgende Formel ein =WENN(A1="";D1*E1;"x")
  • beenden Sie die Aufzeichnung
=WENN(A1="";D1*E1;"x") mal in Sprache übersetzt
(wenn in der Zelle A1 nichts steht, multipliziere Zelle D1 mit E1 ansonsten schreibe den Text x in die Zelle)

folgendes müsste jetzt im Modul stehen
Code:

Sub Formel()
    Range("H1").Select
    ActiveCell.FormulaR1C1 = "=IF(RC[-7]="""",RC[-4]*RC[-3],""x"")"
    Range("H2").Select
End Sub
vom vorigen Bsp. wissen wir ja schon Select wird nicht benötigt und ein .formula gibt es auch.
Code:

Sub Formel()
    Range("H1").Formula = "=IF(A1="""",D1*E1,""x"")"
End Sub
Ich glaube fast der Code spricht für sich, entscheiden Sie selber, welcher von den Beiden besser lesbar ist.

Nun geht es weiter mit dem Objektmodell:
Angenommen ich möchte etwas in einem anderen Tabellenblatt ausführen.
Zeichnen Sie einmal folgendes auf.
  • Starten Sie die Aufzeichnung
  • vergeben Sie für das Makro den Namen kopieren
  • Markieren sie in der Tabelle1 den Bereich von C4:C6
  • kopieren Sie diesen
  • wechseln Sie auf die Tabelle2
  • klicken Sie auf die Zelle C4
  • Befehl einfügen
  • beenden Sie die Aufzeichnung.
folgendes müsste jetzt vorliegen
Code:

Sub kopiere()
    Range("C4:C6").Select
    Selection.Copy
    Sheets("Tabelle2").Select
    Range("C3").Select
    ActiveSheet.Paste
End Sub
diesen Code bauen wir jetzt um

Code:

Sub kopiere()
    'kopiere den Bereich C4 bis C6 des
    'aktiven Tabellenblattes nach Tabelle2 in die Startzelle C4
    Range("C4:C6").Copy Sheets("Tabelle2").Range("C4")
End Sub
sehen wir uns einmal das Objektmodell an indem wir unsere Referenz um das Worksheet erweitern

möchte ich, dass in einem bestimmten Tabellenblatt etwas ausgeführt wird, kann folgendes verwendet werden.

Code:

'die Makros können von einem beliebigen Tabellenblatt aufgerufen werden
Sub bestimmtes_Tabellenblatt1()
'in der Tabelle mit dem Namen Tabelle1 wird in Zelle A1 der Text Test eingefügt
'worksheets = "normales" Tabellenblatt
'Vorteil: Code ist leicht lesbar
'Nachteil: wird der Name des Tabellenblattes geändert tritt ein Fehler auf
Worksheets("Tabelle1").Range("A1").Value = "Test"
End Sub
 
Sub bestimmtes_Tabellenblatt2()
'in der Tabelle mit dem Namen Tabelle1 wird in Zelle A1 der Text Test eingefügt
'Sheets = alle Tabellenblatter (auch Diagrammblätter können damit angesprochen werden)
'Vorteil: Code ist leicht lesbar
'Nachteil: wird der Name des Tabellenblattes geändert tritt ein Fehler auf
Sheets("Tabelle1").Range("A1").Value = "Test"
End Sub
 
Sub bestimmtes_Tabellenblatt3()
'in der ERSTEN Tabelle wird in Zelle A1 der Text Test eingefügt
'Sheets = alle Tabellenblatter (auch Diagrammblätter können damit angesprochen werden)
'Vorteil: es wird jetzt immer das erste Tabellenblatt genommen, leicht über Schleifen steuerbar
'Nachteil: wird die Tabelle verschoben, wird im falschen Tabellenblatt der Eintrag erfolgen
Sheets(1).Range("A1").Value = "Test"
End Sub
 
Sub bestimmtes_Tabellenblatt4()
'in der Tabelle mit dem CODENAMEN Tabelle1 wird in Zelle A1 der Text Test eingefügt
'der Codenamen einer Tabelle ist der Name der im VBAProject der Tabelle an erster Stelle steht (der Name vor der Klammer)
'und kann geändert werden wenn man im Opjektexplorer das jeweilige Tabellenblatt markiert
'und im Eigenschaftsfenster bei Name den Namen ändert
'Vorteil: der Tabellenblattname kann vom User umbenannt werden, der Code wird denoch im richtigen Blatt ausgeführt
'Nachteil: nicht so leicht über Schleifen steuerbar wie sheets(index)
Tabelle1.Range("A1").Value = "Test"
End Sub
Möchte ich nun sichergehen, dass aus der Tabelle1 kopiert wird, würde ich folgendes empfehlen.
Code:

Sub kopiere()
    Sheets("Tabelle1").Range("C4:C6").Copy Sheets("Tabelle2").Range("C4")
End Sub
so das wars mal fürs erste.

eine sehr gute Erklärung finden sie auch hier
http://www.online-excel.de/excel/singsel_vba.php?f=78

alle VBACodes wurden mit
Code eingefügt mit dem MOF Code Converter
eingefügt.

__________________

Gruß Chris

Feedback nicht vergessen,
p.s Bitte keine PN (persönliche Nachrichten) mit Aufgabenstellungen schicken, Probleme sollten im Forum gelöst werden!
3a2920576572206973742064656e20646120736f206e65756769657269672e

Geändert von chris-kaiser (25.03.2010 um 13:34 Uhr).
chris-kaiser ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 28.10.2010, 09:14   #2
chris-kaiser
Threadstarter Threadstarter
MOF Guru
MOF Guru
Standard Excel im "Hintergrund" öffnen

Hallo Allerseits

da ich in letzter Zeit immer wieder lese, "wie kann ich im Hintergrund Excel öffnen".
Habe ich dazu ein paar Tutorials erstellt.

Code:

'dieser Code kann in Word,Excel,Acc verwendet werden
Sub im_Hintergrund_neue_mappe_anlegen()
 
'falls ein Fehler auftritt gehe zur Fehlerbehandlung
On Error GoTo errhandler
Dim objAppExcel As Object
Dim objWb As Object
Dim objSH As Object
 
'ich starte eine NEUE Instanz von Excel, es würde auch noch ein Getobject geben
'kombiniert mit einer Fehlerroutine das lasse ich aber einmal weg
Set objAppExcel = CreateObject("Excel.Application")
 
'Erstelle eine neue Mappe
Set objWb = objAppExcel.Workbooks.Add
'hier bekommt das Tabellenblatt1 den Namen "neuer_Blattname"
Set objSH = objWb.Sheets(1)
objSH.Name = "neuer_Blattname"
 
'in die Zelle A1 schreibe ich den Text "Text1"
objSH.Cells(1, 1).Value = "Text1"
 
'jetzt speichere ich die Mappe auf c:\temp mit dem Namen "neue_Mappe"
'objWb.SaveAs "C:\Temp\neue_Mappe.xls"
'würde der Code nochmal ausgeführt werden würde kommt eine Abfrage ob die Datei überschrieben werden sollte
 
'soll die Datei überschrieben werden
objAppExcel.DisplayAlerts = False
objWb.SaveAs "C:\Temp\neue_Mappe.xls"
objAppExcel.DisplayAlerts = True
 
objAppExcel.Quit
Set objSH = Nothing
Set objWb = Nothing
Set objAppExcel = Nothing
Exit Sub
 
errhandler:
MsgBox "Fehlernr:" & Err.Number & " " & Err.Description
objWb.Close savechanges:=False
objAppExcel.Quit
Set objSH = Nothing
Set objWb = Nothing
Set objAppExcel = Nothing
 
End Sub

soll etwas in einer bestehenden Instanz "unsichtbar" aufgemacht werden

Code:

'dieser Code kann in jetzt NUR Excel verwendet werden
Sub im_Hintergrund_bestehende_mappe_oeffnen()
 
'falls ein Fehler auftritt gehe zur Fehlerbehandlung
On Error GoTo errhandler
Dim objWb As Object
Dim objSH As Object
'aktuelle Mappe merken (die gerade offene)
Dim AktuelleMappe As Workbook
Set AktuelleMappe = ActiveWorkbook
'keine neue Instanz von Excel sondern öffne diese in der bestehenden Anwendung mit getobject
'vorteil gegenüber open ist der das getobject mit visible false arbeitet
Set objWb = GetObject("C:\Temp\neue_Mappe.xls")
 
Set objSH = objWb.Sheets(1)
'kopiere Zelle A1 von der im Hintergrund offenen Mappe auf die aktuell sichtbare Mappe in das erste Blatt Zelle A1
objSH.Cells(1, 1).Copy AktuelleMappe.Sheets(1).Cells(1, 1)
 
'schließe die "unsichtbare" Mappe ohne speichern
objWb.Close savechanges:=False
 
Set objSH = Nothing
Set objWb = Nothing
Exit Sub
 
errhandler:
MsgBox "Fehlernr:" & Err.Number & " " & Err.Description
objWb.Close savechanges:=False
Set objSH = Nothing
Set objWb = Nothing
End Sub
 
 

jetzt noch eine Spielerei wo ich Daten aus einer "unsichtbaren" Mappe in die aktuelle übertrage.

Code:

Option Explicit
Sub im_Hintergrund_bestehende_mappe_oeffnen()
'falls ein Fehler auftritt gehe zur Fehlerbehandlung
On Error GoTo errhandler
Dim objAppExcel As Object
Dim objWb As Object
Dim objSH As Object
Dim lngLastrow As Long
Dim AktuelleMappe As Workbook
Set AktuelleMappe = ActiveWorkbook
'ich starte eine NEUE Instanz von Excel
Set objAppExcel = CreateObject("Excel.Application")
 
'Oeffne eine bestehende Mappe 'kann natürlich auch mit einem Dialog kombiniert werden
Set objWb = objAppExcel.Workbooks.Open("C:\Temp\neue_Mappe.xls")
 
Set objSH = objWb.Sheets(1)
'Alle Daten in Spalte A in die bestehende Mappe übertragen
With objSH
    'letzte befüllte Zelle in Spalte A der im Hintergrund offenen Datei
    lngLastrow = .Cells(.Rows.Count, 1).End(xlUp).Row
    'es würde jetzt viele Möglichkeiten geben die Daten in das aktuelle Blatt zu bringen, ich mache es hier einmal über ein VariantenArray
    Dim rngArr
    rngArr = .Range(.Cells(1, 1), .Cells(lngLastrow, 1))
End With
'hier die Übergabe an die aktuelle Mappe
AktuelleMappe.Sheets(1).Range(Cells(1, 1), Cells(lngLastrow, 1)).Value = rngArr
 
objAppExcel.Quit
objWb.Close savechanges:=False
Set objSH = Nothing
Set objWb = Nothing
Set objAppExcel = Nothing
Exit Sub
 
errhandler:
MsgBox "Fehlernr:" & Err.Number & " " & Err.Description
objWb.Close savechanges:=False
objAppExcel.Quit
Set objSH = Nothing
Set objWb = Nothing
Set objAppExcel = Nothing
 
End Sub
 
 
Code eingefügt mit dem MOF Code Converter

__________________

Gruß Chris

Feedback nicht vergessen,
p.s Bitte keine PN (persönliche Nachrichten) mit Aufgabenstellungen schicken, Probleme sollten im Forum gelöst werden!
3a2920576572206973742064656e20646120736f206e65756769657269672e

Geändert von chris-kaiser (28.10.2010 um 09:20 Uhr).
chris-kaiser ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 28.10.2010, 14:16   #3
hary
MOF Guru
MOF Guru
Standard

Hallo Chris
Danke fuer die Muehe des zusammenfassens.
gruss hary
hary ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 15.06.2011, 12:20   #4
hugolee
MOF User
MOF User
Standard

Hallo Chris,

DANKE für die Mühe!

Ich will folgenden Code schlanker machen.

Zitat:

'Quelle
Q_Anfang = [D21]
Q_Anzahl = [E21]
Q_Ziel = Q_Anfang + Q_Anzahl - 1
'Ziel
Z_Anfang = [D20]
Z_Anzahl = Q_Anzahl
Z_Ziel = Z_Anfang + Z_Anzahl - 1

'Anzahl merken
[F21] = [E21]

'ab hier schlanker machen...


'Kopiervorgang
Sheets("Import").Select
ActiveSheet.Rows(Q_Anfang & ":" & Q_Ziel).Select
Selection.Copy
Sheets("Sicherung").Select
ActiveSheet.Rows(Z_Anfang & ":" & Z_Ziel).Select
Selection.Insert Shift:=xlDown

Das Copy und Paste schlanker machen geht auch wunderbar, aber das Einfügen (neue Zeilen einfügen) bekomme ich dann nicht hin.
Wie geht das denn?

DANKE
hugolee
hugolee ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 18.06.2011, 06:37   #5
Beverly
MOF Guru
MOF Guru
Standard

Hi Hugo,
Code:

Sheets("Import").Rows(Q_Anfang & ":" & Q_Ziel).Copy
Sheets("Sicherung").Rows(Z_Anfang & ":" & Z_Ziel).Insert Shift:=xlDown
Application.CutCopyMode = False

GrußformelBeverly's Excel - Inn
Beverly ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 18.06.2011, 22:51   #6
hugolee
MOF User
MOF User
Standard

DANKE Beverly !!!
hugolee ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 19.06.2011, 22:45   #7
chris-kaiser
Threadstarter Threadstarter
MOF Guru
MOF Guru
Standard

Hallo Hugo

sry, erst jetzt gesehen... ich komme im Moment einfach zeitlich nicht dazu ins
Forum zu schauen bzw. auch was zu schreiben..
Ich hoffe das ändert sich bald...
und danke an Karin!

__________________

Gruß Chris

Feedback nicht vergessen,
p.s Bitte keine PN (persönliche Nachrichten) mit Aufgabenstellungen schicken, Probleme sollten im Forum gelöst werden!
3a2920576572206973742064656e20646120736f206e65756769657269672e
chris-kaiser ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 18.01.2012, 17:40   #8
Schnutzkurt
Neuer Benutzer
Neuer Benutzer
Standard

Hallo
Ich hoffe ich bin hier richtig mit meinem anliegen.

möchte per schaltknopf ein bild in einem ordner auf der festplatte auswählen das dann verkleinert in die active zelle eingefügt wird und beim drauf klicken gößer wird
danke für eure hilfe
Schnutzkurt ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 18.01.2012, 17:58   #9
EarlFred
MOF Guru
MOF Guru
Standard

Hallo,

Zitat:

Ich hoffe ich bin hier richtig mit meinem anliegen.

Der Artikel sollte eher eine allgemeine Hilfestellung und Anleitung sein. Konkrete Fragen, die nichts mit dem Artikel direkt zu tun haben, bitte in einem eigenen Thread im Forum eröffnen, damit dieser hier übersichtlich bleibt. Im Forum wird Dir bestimmt jemand helfen.

Grüße
EarlFred

__________________

Datum und Uhrzeit, Makrorekorder-Code entschlacken, {Matrixformeln}
Tutorials zu Pivottabellen: Kurzeinstieg; Dynamischer Datenbereich; Daten und Zeiten gruppieren
Für 5 meiner Beiträge haben sich die Hilfesuchenden mit einer Spende an Wikipedia, die Tafeln oder Hilfe für krebskranke Kinder eV bedankt (das entspricht 0,037% per 04.04.2018) - eine tolle Geste!
EarlFred ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 19.01.2012, 05:16   #10
Schnutzkurt
Neuer Benutzer
Neuer Benutzer
Standard

Danke für die rasche antwort

war auf der suche und habe deinen artikel ob gelesen der sehr ausführlich und für ein VB wields.. wie mich auch verständlich ist
da ich das makro dringend benötige habe ich mich auf diesem weg herangewagt
dachte es sind ein paar zeilen code die hier her passen

trotzdem danke
Schnutzkurt ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 19.01.2012, 07:55   #11
EarlFred
MOF Guru
MOF Guru
Standard

Hallo,

Du kannst doch einfach ein neues Thema erstellen:
http://www.ms-office-forum.de/forum/...splay.php?f=29
Unten Links auf den Button "Neues Thema" und dort Deine Frage erstellen (hineinkopieren). Es findet sich bestimmt wer, der was dazu schreiben kann.

Grüße
EarlFred

__________________

Datum und Uhrzeit, Makrorekorder-Code entschlacken, {Matrixformeln}
Tutorials zu Pivottabellen: Kurzeinstieg; Dynamischer Datenbereich; Daten und Zeiten gruppieren
Für 5 meiner Beiträge haben sich die Hilfesuchenden mit einer Spende an Wikipedia, die Tafeln oder Hilfe für krebskranke Kinder eV bedankt (das entspricht 0,037% per 04.04.2018) - eine tolle Geste!
EarlFred ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 23.07.2015, 07:24   #12
MrLinux
Neuer Benutzer
Neuer Benutzer
Standard

Danke - genau die Erklärungen, nach denen ich gesucht habe

Gruß,
MrLinux
MrLinux ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Ads
Antworten


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Besucher: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist Ihnen nicht erlaubt, neue Themen zu verfassen.
Es ist Ihnen nicht erlaubt, auf Beiträge zu antworten.
Es ist Ihnen nicht erlaubt, Anhänge anzufügen.
Es ist Ihnen nicht erlaubt, Ihre Beiträge zu bearbeiten.

vB Code ist An.
Smileys sind An.
[IMG] Code ist An.
HTML-Code ist An.
Gehe zu


Alle Zeitangaben in WEZ +1. Es ist jetzt 20:34 Uhr.


Partner und Co.
Access-Paradies -Alles rund um die Datenbank Microsoft Access -Code -Programme-Tools -Tipps   Kostenlose Tipps & Tricks, Downloads und Programme   www.kulpa-online.com - Tipps - Tricks - Tutorials - Meinungen - Downloads uvm...   vb@rchiv · Willkommen in der Welt der VB Programmierung   Access-Garhammer - Hier finden Sie jede Menge Beispiel-Datenbanken zu Access und mehr ...   mcseboard.de   Die Top Seite für Excel-VBA-Makros uvm.

Powered by: vBulletin Version 3.6.2 (Deutsch)
Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.

Copyright ©2000-2018 MS-Office-Forum. Alle Rechte vorbehalten.
Copyright ©Design: Manuela Kulpa ©Rechte: Günter Kramer
Eine Verwendung der Inhalte in anderen Publikationen, auch auszugsweise,
ist ohne ausdrückliche Zustimmung der Autoren nicht gestattet.