Sonstiges - Vgl. 2er DLookUp-Varianten

[#_Columbo_#]

Hi,

sind folgende Anweisungen gleichwertig, bzw. wo liegen die Vor- u. Nachteile?
Zweck der Anweisungen/Funktionen: Übergabe eines einzelnen Wertes aus einer SQl-Abfrage an eine Variable.

Code:

Variable = CurrentDbC.OpenRecordset(strSQL, dbOpenForwardOnly)(0)

und

Code:

Public Function fn_DLookupSQL(strSQL As String) As Variant
  Dim rs As DAO.Recordset
  Set rs = CurrentDbC.OpenRecordset(sSQL, dbOpenForwardOnly)
  With rs
    If .EOF Then
      fn_DLookupSQL = Null
    Else
      fn_DLookupSQL = .Fields(0)
    End If
    .Close
  End With
  Set rs = Nothing
End Function

Variable = fn_DLookUpSQL(strSQL)

1. Wird im ersten Fall eine Recordset geöffnet?
2. Wird es auch wieder geschlossen?
3. Ist (0) der Feldindex des Recordsets?

[hcscherzer]

Moin Frank,

Hast Du beide Varianten mal ausprobiert ???

ich bin nicht sicher, ob #1 überhaupt etwas liefert: die Prozedur OpenRecordset liefert eine Recordset-Objektvariable und die muss per 'set variable = ' zugewiesen werden. Auch die Schreibweise mit dem Index 0 habe ich noch nie gesehen.

#2 liefert NULL, wenn das RecordSet leer ist aber wenn nicht?
.fields(0) ist wiederum ein Objekt und die Zuweisung sollte per 'Set' erfolgen.

Code:

fn_DLookupSQL = .Fields(0).Name 'liefert den Namen des ersten Felds
fn_DLookupSQL = !Fields(0) ' liefert den Inhalt des ersten Felds aus dem ersten Datensatz

[#_Columbo_#]

Hi Hans-Christian,

beides funktioniert einwandfrei und bringen das gleiche Ergebnis

Zitat:

#2 liefert NULL, wenn das RecordSet leer ist aber wenn nicht?

Bei folgender SQL-Abfrage wird immer EIN Ergebnis geliefert:

Code:

"SELECT Max(ID) FROM tblFilme;"

Zitat:

fn_DLookupSQL = !Fields(0) ' liefert den Inhalt des ersten Felds aus dem ersten Datensatz

liefert aber einen Fehler. Eigentlich logisch, da Fields ja kein definiertes Feld ist, sondern die Feld-Auflistung des Recordsets und da ist die !-Schreibweise IMHO falsch.

[ebs17]

Die zweite Variante ist die von Josef P., wenn ich mich nicht schwer irre, und ist deswegen alleine schon sauber. Beim leeren Recordset wird analog DLookup Null zurückgegeben.
Bei der ersten Variante müsste man mal testen, wie der Umgang ist, wenn die SQL-Anweisung kein Ergebnis bringt. Das wird der einzige Knackpunkt sein.

[#_Columbo_#]

Hallo Eberhard,

Zitat:

Die zweite Variante ist die von Josef P., wenn ich mich nicht schwer irre, und ist deswegen alleine schon sauber. Beim leeren Recordset wird analog DLookup Null zurückgegeben.

Da hast Du vollkommen recht und läuft natürlich auch hervorragend

Zitat:

Bei der ersten Variante müsste man mal testen, wie der Umgang ist, wenn die SQL-Anweisung kein Ergebnis bringt. Das wird der einzige Knackpunkt sein.

Code:

  varID = CurrentDbC.OpenRecordset("SELECT Max(ID) FROM tblLeer;", dbOpenForwardOnly)(0)

liefert NULL zurück, wobei tblLeer eine leere Tabelle OHNE Datensätze und Felder ist und daher die Funktion Max(ID) keinen Wert zurückgibt.

[#_Columbo_#]

Code:

  Variable = CurrentDbC.OpenRecordset("SELECT Max(ID), Filmtitel FROM tblFilme GROUP BY Filmtitel;", dbOpenForwardOnly)(1)

die eingeklammerte Zahl ist der Feldindex des Recordset. Hier der Filmtitel

Code:

  Variable = CurrentDbC.OpenRecordset("SELECT Max(ID), Filmtitel FROM tblFilme GROUP BY Filmtitel;", dbOpenForwardOnly)(0)

hier die ID

!!! Bei dieser Schreibweise ist die Angabe des Feldindexes (n) scheinbar unbedingt erforderlich, da sonst Fehlermeldung !!!

[Josef P.]

Anm.:

Code:

Variable = CurrentDbC.OpenRecordset(...)(0)

steht für

Code:

Variable = CurrentDbC.OpenRecordset(...).Fields(0)

weil Fields das Standardelement von Recordset ist.
CurrentDbC.OpenRecordset(...) ... liefert als Ergebnis ein Recordset, das man im Prinzip ohne Umweg einer Variablen verwenden kann.
symbolisch: [Recordset aus CurrentDbC.OpenRecordset(..)].Fields(0)

Wenn es keinen Datensatz gibt, kann aber Recordset.Fields(0) nicht ausgewertet werden und es kommt zu einem Fehler.

[#_Columbo_#]

Hi Josef,

Zitat:

CurrentDbC.OpenRecordset(...) ... liefert als Ergebnis ein Recordset, das man im Prinzip ohne Umweg einer Variablen verwenden kann.
symbolisch: [Recordset aus CurrentDbC.OpenRecordset(..)].Fields(0)

Danke, sowas in der Art hatte ich auch vermutet (siehe #6)

Zitat:

Wenn es keinen Datensatz gibt, kann aber Recordset.Fields(0) nicht ausgewertet werden und es kommt zu einem Fehler.

Hmmm.... NULL = Fehler ????? -> s. Posting #5

[Josef P.]

Zitat:

Hmmm.... NULL = Fehler ????? -> s. Posting #5

Nein, NULL führt zu keinem Fehler. Nur wenn kein DS vorhanden ist, kommt es zu einem Fehler.
z. B.:

Code:

 varID = CurrentDbC.OpenRecordset("SELECT id FROM tblLeer", dbOpenForwardOnly)(0)

oder

Code:

varID = CurrentDbC.OpenRecordset("SELECT max(id) FROM tblLeer group by ID", dbOpenForwardOnly)(0)

[ebs17]

Jetzt musste ich doch einmal testen - und frage mich, was Du getestet hast.

Zitat:

liefert NULL zurück, wobei tblLeer eine leere Tabelle OHNE Datensätze und Felder ist

Ich scheitere schon daran, eine Tabelle ohne Felder anzulegen.

Der gezeigte Test mit Max auf eine Tabelle ohne Datensätze ergibt in der Tat Null.

Der Test einer ganz normalen Auswahlabfrage (ebenso typisch für DLookup) mit

Code:

sSQL = "SELECT * FROM tab WHERE ID = 100"

..., wobei ID 100 in der Tabelle nicht vorhanden ist, ergibt LZF 3021 (Kein aktueller Datensatz).

[#_Columbo_#]

Hi Josef,

ich glaube ich hab's verstanden:
Bei existierenden Tabellen MIT Datensätzen kann ich die Kurzvariante nehmen

Wenn ich mir da mal nicht so sicher sein sollte, dann doch lieber die ausführliche Variante von Dir

[#_Columbo_#]

@Eberhard,

sorry das Du Dir die Arbeit gemacht hast, mein Problem nachzuvollziehen

Ich hatte in der Tat nur folgende Zeile angetestet gehabt und die lieferte halt NULL:

Zitat:

varID = CurrentDbC.OpenRecordset("SELECT Max(ID) FROM tblLeer;", dbOpenForwardOnly)(0)

Asche über mein Haupt
Bei leeren Tabellen gibts also meist Fehlermeldungen bei dieser Version

[Josef P.]

Die ausführliche Variante wird schnell kurz, wenn man sie in eine Hilfsfunktion steckt. (So wie im Beitrag #1 gezeigt)
Wenn dann später nur noch diese Hilfsfunktion verwendet wird, ist es doch völlig egal wieviele Zeilen in dieser Hilfsfunktion stecken.

Eine Funktion, die ich gerne einsetze:

Code:

Public Function DLookupSQL(ByVal sSQL As String, Optional ByVal index As Variant = 0&) As Variant

    Dim rst As DAO.Recordset

    Set rst = CurrentDbC.OpenRecordset(sSQL, dbOpenForwardOnly, dbSeeChanges, dbReadOnly)
    With rst
        If .EOF Then
            DLookupSQL = Null
        Else
            DLookupSQL = .Fields(index)
        End If
        .Close
    End With
    Set rst = Nothing

End Function

=>

Code:

varID = DLookupSQL("SELECT id FROM tblLeer")

[ebs17]

Zitat:

Bei existierenden Tabellen MIT Datensätzen kann ich die Kurzvariante nehmen

Wenn es mit Sicherheit den gewünschten Datensatz laut Kriterium gibt. Wer kann das schon sagen?

Ein Test, ob ein bestimmter Datensatz/Eintrag vorhanden ist, sollte somit mit der Kurzvariante tunlichst unterlassen werden.

Fazit: Die Langvariante ist universeller und in der Schreibarbeit kürzer, die einmalige Deklaration der Funktion (Kopieren in ein Modul) kann man als Aufwand vernachlässigen.