MS-Office-Forum

Zurück   MS-Office-Forum > Microsoft Office > Microsoft Excel
Registrieren Forum Hilfe Alle Foren als gelesen markieren

Banner und Co.

Antworten
Ads
Themen-Optionen Ansicht
Alt 21.03.2019, 11:37   #16
Der Steuerfuzzi
MOF Profi
MOF Profi
Standard

Da der Code Daten vom ersten Blatt in das zweite Blatt kopiert, werden auch die Formate mitkopiert. Es muss also auch die ganze Spalte D im ersten Blatt ohne Sperre sein. Hast Du das auch gemacht?

__________________

Gruß
Michael
Der Steuerfuzzi ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 21.03.2019, 23:06   #17
Quartzlurch
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hallo Michael,

ja, auch das habe ich gemacht. Habe mittlerweile heraus gefunden, wenn ich im ersten Blatt ein "x" habe, also doppelte kopiere, dann passiert das nicht. Das kommt nur vor, wenn doppelte gelöscht werden. Komisch, oder? Dir noch eine gute Nacht.

Gruß Horst
Quartzlurch ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 22.03.2019, 09:44   #18
Der Steuerfuzzi
MOF Profi
MOF Profi
Standard

Ich habe mir das mal angesehen. Es ist tatsächlich so, dass die Zellen, die durch die Funktion "Duplikate entfernen" gelöscht werden, als gesperrt gekennzeichnet werden. Ich kann es mir leider nicht plausibel erklären, warum das passiert, aber dann heben wir die Sperre eben per Code wieder auf. Bitte den ganzen Code in Deine Datei kopieren (ich habe noch zwei kleine Fehler gefunden):
Code:

Sub Zeilen_in_Falsche_Vokabeln1_kopieren()
    ' Die Zeilen falsch beantworteter Vokabeln werden
    ' in das Tabellenblatt "Falsche Vokabeln1" kopiert

    Dim i       As Long
    Dim tarWks  As Worksheet
    Dim srcWks  As Worksheet
        
    i = MsgBox("Sollen die Daten wirklich übertragen werden?" _
        & vbCr & "Gute Entscheidung nochmal zu wiederholen!!!", vbYesNo + vbQuestion, "Frage vom Lehrer!")
    
    If i = vbYes Then
        Application.ScreenUpdating = False   'Schaltet den Bildschirm aus
        Set srcWks = Worksheets("Vokabeln")
        Set tarWks = Worksheets("Falsche Vokabeln1")
        ' Schreibschutz_aufheben ausgelagert in eine eigene Sub:
        Schutz_aus srcWks
        Schutz_aus tarWks
        With srcWks
             'Autofilter: nur "Fehler" sichtbar
             If Not .AutoFilterMode Then Range("A1").AutoFilter 'Wenn im Blatt kein Autofilter, dann Filter setzen
             .Range("A1").AutoFilter Field:=5, Criteria1:="Fehler" 'Die Daten mit Werten "Fehler" in Spalte 5 filtern
             'Sichtbare Zellen in das Blatt "Falsche Vokabeln1" kopieren:
             .Range(.Cells(2, 1), .Cells(.Rows.Count, 3).End(xlUp)).SpecialCells(xlCellTypeVisible).Copy tarWks.Cells(Rows.Count, "A").End(xlUp).Offset(1, 0)
             If .AutoFilterMode Then .Range("A1").AutoFilter 'Wenn der Autofilter gesetzt ist, dann Filter abschalten
             'Fomel eintragen
                 'Formel in Spalte E einfügen:
             tarWks.Range("E2:E" & .Cells(Rows.Count, "A").End(xlUp).Row).FormulaR1C1 = _
                         "=IF(ISBLANK(RC[-1]),"""",IF(ISNA(MATCH(RC[-1],RC[1],0)), ""Fehler"",""richtig""))"
        End With
        'Der einzige Unterschied: Wenn ein x in J18 gesetzt ist, werden die Duplikate im Blatt "Falsche Vokabeln1" entfernt:
        If srcWks.Range("J18") <> "x" Then
             With tarWks
                'Alle doppelten Vokabeln löschen
                .Range("$A$1:$E" & .Cells(Rows.Count, "A").End(xlUp).Row).RemoveDuplicates _
                 Columns:=1, Header:=xlYes
                 .Range("D:D").Locked = False
             End With
         End If
        Schutz_an srcWks
        Schutz_an tarWks
        tarWks.Activate
        Set srcWks = Nothing
        Set tarWks = Nothing
        Application.ScreenUpdating = True   'Schaltet den Bildschirm ein
    Else
        MsgBox "OK, die Daten werden nicht übertragen!"
    End If
End Sub
Sub Schutz_aus(wks As Worksheet)
    wks.Unprotect Password:=""
    wks.Columns("A:H").Hidden = False
End Sub
Sub Schutz_an(wks As Worksheet)
    wks.Range("B:B, G:G").EntireColumn.Hidden = True
    wks.Protect Password:="", DrawingObjects:=True, Contents:=True, Scenarios:=True
End Sub

__________________

Gruß
Michael
Der Steuerfuzzi ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 22.03.2019, 11:36   #19
Quartzlurch
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hallo Michael,

perfekt, das war die finale Lösung! Die Spalte "D" hat jetzt zwar die Zelle "D1" auch ungeschützt, das habe ich aber im Code wie folgt geändert:

Code:

With tarWks
                'Alle doppelten Vokabeln löschen
                .Range("$A$1:$E" & .Cells(Rows.Count, "A").End(xlUp).Row).RemoveDuplicates _
                 Columns:=1, Header:=xlYes
                 .Range("D:D").Locked = False
                 .Range("D1").Locked = True
             End With
Vielen lieben Dank nochmal für deine Geduld und Hilfsbereitschaft. Großartig!!!

Liebe Grüße Horst

Dir ein schönes Wochenende
Quartzlurch ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 22.03.2019, 12:15   #20
Der Steuerfuzzi
MOF Profi
MOF Profi
Standard

Hallo Host,

gerne. Auch Dir ein schönes Wochenende.

__________________

Gruß
Michael
Der Steuerfuzzi ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Ads
Antworten


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Besucher: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist Ihnen nicht erlaubt, neue Themen zu verfassen.
Es ist Ihnen nicht erlaubt, auf Beiträge zu antworten.
Es ist Ihnen nicht erlaubt, Anhänge anzufügen.
Es ist Ihnen nicht erlaubt, Ihre Beiträge zu bearbeiten.

vB Code ist An.
Smileys sind An.
[IMG] Code ist An.
HTML-Code ist An.
Gehe zu


Alle Zeitangaben in WEZ +1. Es ist jetzt 14:14 Uhr.



Powered by: vBulletin Version 3.6.2 (Deutsch)
Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.

Copyright ©2000-2018 MS-Office-Forum. Alle Rechte vorbehalten.
Copyright ©Design: Manuela Kulpa ©Rechte: Günter Kramer
Eine Verwendung der Inhalte in anderen Publikationen, auch auszugsweise,
ist ohne ausdrückliche Zustimmung der Autoren nicht gestattet.