PDA

Vollständige Version anzeigen : CDO.Message und Der "SendUsing"-Konfigurationswert ist ungültig


Lupus
08.06.2003, 21:24
Hallöschen,

Ich bin kurz vor dem Herzinfakt:
(Bin ich denn hier richtig?)
System: WIN XP Prof.
Internet-Informationsdienste 5.1
Eingetragen in der RegEdit ist unter
InprocServer32 <C:\WINDOWS\System32\cdosys.dll>

und dann dies:

Code:
Set Mailer = CreateObject("CDO.Message")
' --- Absender und Empfänger einstellen
Mailer.From = "Lupusverlach <webmaster@lupusdw.de>"
Mailer.To = im_email
' --- Betreff und Mailtext einstellen
Mailer.Subject = im_betreff
Mailer.TextBody = Message
' --- EMail versenden
Mailer.Send
Set Mailer= Nothing

Beim Absenden kommt eine Fehlermeldung:

Fehlermeldung:
Fehlertyp:
CDO.Message.1 (0x80040220)
Der "SendUsing"-Konfigurationswert ist ungültig.
/lupusdw/danke.asp, line 40

In der Zeile 40 steht: Mailer.Send

Auf meinem localhost geht es nicht, bei meinem Provider (WIN 2000 IIS 5.0) jedoch keine schwierigkeiten.

Habe mich schon zu tote gegoogle aber nix gefunden.

Al3x
13.06.2003, 09:05
Hi Lupus,

soweit ich es verstanden habe, benutzt CDO Standardmässig den lokal Installierten SMTP Server zum verschicken der Mails, man kann das auch anders Konfigurieren, das er z.B. einen Remote SMTP Server benutzen soll.
Ich vermute daher das du auf deiner Lokalen Maschine nur den IIS Installiert hast aber keinen SMTP Server (wer hat das auch schon), es kann auch sein das ich mit meiner Vermutung falsch liege.

Aber du könntest einfach mal einen Remote SMTP beim Versenden benutzen, hier mal ein kurzes Test Script (geklaut :-))



Set objMessage = CreateObject("CDO.Message")
objMessage.Subject = "Example CDO Message"
objMessage.Sender = "me@my.com"
objMessage.To = "test@paulsadowski.com"
objMessage.TextBody = "This is some sample message text."

'==This section provides the configuration information for the remote SMTP server.
'==Normally you will only change the server name or IP.

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.myserver.com"

'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

objMessage.Configuration.Fields.Update

'==End remote SMTP server configuration section==

objMessage.Send


Vieleicht noch Intressant :
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/cdosys/html/_cdosys_cdosendusing_enum.asp
gruß
Alex