PDA

Vollständige Version anzeigen : HILFE Fragebogen in Excel erstellen und Outlook versenden


ReccMar
18.11.2008, 09:22
Guten Morgen miteinander:)

Ich muss für meine Firma einen Fragebogen erstellen der mit Outlook versendet werden soll. BZW. dieser Fragebogen wird an unseren Newsletter angehängt. Es sind nur 5-6 Fragen mit jeweils 3 Antwortmöglichkeiten.
Also es handelt sich nicht um "JA/NEIN" oder "sehr gut-ungenügend" Fragen, sondern um Antwortmöglichkeiten die vorgegeben sind und man muss eine anklicken oder ein kreuzchen daheinter setzen.
(Was wollen Sie essen?
Fisch
Fleisch
Vegetarisch)

jetzt habe ich erst mal nach "Fragebogen outlook" gegoogelt und bin dann auf eine Seite gestoßen in der es hieß ich müsse den fragebogen in excel erstellen und dann über outlook versenden.


Nur weiß ich leider auch überhaupt nicht wie man mit Excel einen Fragebogen Erstellt :(

Kann mir da jemand helfen? Bitte?

Danke schonmal im vorraus.

Lg Maria
ps ich arbeite mit Excel 2007 falls das Unterschiede macht.

jinx
18.11.2008, 10:18
Moin, Maria,

hängt von der weiteren Verwendung ab. Eine Excelmappe sollte als Anhang versandt werden und dann auch immer als Anhang zurückkommen. Bei eiern Verwendung von Outlook ließe sich dort eine Umfrage anhängen, die direkt zurückgeschickt werden kann. Es kommt darauf an, wie die Angaben weiterverarbeitet werden sollen...

Eine Möglichkeit der Auswertung von Optionbuttons aus Excelmappen per VBA:

Sub ÜbersichtAuswertung()

Dim oGroupBox As GroupBox
Dim oOptBtn As OptionButton
Dim lngAntworten As Long
Dim rngZelle As Range
Dim rngBereich As Range
Dim wsTab As Worksheet
Dim lngZähler As Long
Dim rngErsteZelle As Range
Dim lngFragen As Long
Dim varBorders As Variant

varBorders = Array(xlEdgeLeft, xlEdgeTop, _
xlEdgeBottom, xlEdgeRight, xlInsideVertical, xlInsideHorizontal)

lngAntworten = 5
lngFragen = 10

Set wsTab = ActiveSheet

With wsTab
Set rngErsteZelle = .Range("E2")
.Range("A:I").Clear
With rngErsteZelle.Offset(-1, -1).Resize(1, lngAntworten + 1)
.Value = Array("Frage #", "Antwort1", "Antwort2", _
"Antwort3", "Antwort4", "Antwort5")
.Orientation = 90
.HorizontalAlignment = xlCenter
End With

Set rngBereich = rngErsteZelle.Resize(lngFragen, 1)

With rngBereich.Offset(0, -1)
.Formula = "=row()-" & rngBereich.Row - 1
.Value = .Value
End With

rngBereich.Offset(0, -3).Value = 1

With rngBereich.Offset(0, -4)
.FormulaR1C1 = "=RC[1]*RC[2]"
End With

.Range("A1").Formula = "=SUM(A2:A" & lngFragen + 1 & ")"

With rngBereich.Offset(0, -4).Resize(, 4)
For lngZähler = LBound(varBorders) To UBound(varBorders)
With .Borders(varBorders(lngZähler))
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With
Next lngZähler
.HorizontalAlignment = xlCenter
.VerticalAlignment = xlCenter
End With

rngBereich.EntireRow.RowHeight = 28
rngBereich.Resize(, lngAntworten).EntireColumn.ColumnWidth = 4

.GroupBoxes.Delete
.OptionButtons.Delete

End With

For Each rngZelle In rngBereich
With rngZelle.Resize(1, lngAntworten)
Set oGroupBox = wsTab.GroupBoxes.Add _
(Top:=.Top, Left:=.Left, _
Height:=.Height, Width:=.Width)
With oGroupBox
.Caption = ""
.Visible = True 'False
End With
End With
For lngZähler = 0 To lngAntworten - 1
With rngZelle.Offset(0, lngZähler)
Set oOptBtn = wsTab.OptionButtons.Add _
(Top:=.Top, Left:=.Left, _
Height:=.Height, Width:=.Width)
oOptBtn.Caption = ""
If lngZähler = 0 Then
With rngZelle.Offset(0, -2)
oOptBtn.LinkedCell = .Address(external:=True)
End With
End If
End With
Next lngZähler
Next rngZelle

Set rngBereich = Nothing
Set rngErsteZelle = Nothing
Set wsTab = Nothing

End Sub

Und eine Bitte: dies ist entweder ein Excel- oder ein Outlookthema (http://www.ms-office-forum.net/forum/showthread.php?t=241699), aber nicht sowohl als auch.